#/usr/bin/perl
<<DOC; 
Nom : Rachid Belmouhoub
Avril 2012
 usage : perl bao3_rb_new.pl fichier_tag fichier_motif
DOC
#LE FICHIER MOTIF PEUT CONTENIR PLUSIEURS LIGNES 
#MODULE PERL
#CONSTRUIRE LE CHEMIN XPATH CORRESPONDANT  à un motif pour extraire les formes
#L'extraction est faite par les librairies XML
#LE CHEMIN EST FAIT PAR NOUS 

use strict;
use utf8;
use XML::LibXML;

# Définition globale des encodagees d'entrée et sortie du script à utf8
binmode STDIN,  ':encoding(utf8)';
binmode STDOUT, ':encoding(utf8)';

# On vérifie le nombre d'arguments de l'appel au script ($0 : le nom du script)
if($#ARGV!=1){print "usage : perl $0 fichier_tag fichier_motif";exit;}#fichier xml et fichier motif et on teste sur la variable dollar ; 
#$0 c'est l'exécution du script lui même

# Enregistrement des arguments de la ligne de commande dans les variables idoines, sotcker des arguments de la ligne
my $tag_file= shift @ARGV;
my $patterns_file = shift @ARGV;# renvoie le premier lélement de la liste. le deuxième shift est vide 

# création de l'objet XML::XPath pour explorer le fichier de sortie tree-tagger XML
my $xp = XML::LibXML->new(XML_LIBXML_RECOVER => 2);
$xp->recover_silently(1);
# plusieurs types de parseurs ici DOM et d'autres  SAX =>plus rapide que DOM
my $dom    = $xp->load_xml( location => $tag_file );#le fichier xml de treetager on le charge à cette ligne 
my $root   = $dom->getDocumentElement();#récupère parcours  

my $xpc    = XML::LibXML::XPathContext->new($root);# permet la recherche avec un noeud 

# Ouverture du fichiers de motifs
open(PATTERNSFILE, $patterns_file) or die "can't open $patterns_file: $!\n";#ouvre fichier qui contient les patterns 
#et pour chaque patterns faire ma boucle de forme

# lecture du fichier contenant les motifs, un motif par ligne (par exemple : NOM ADJ)
while (my $ligne = <PATTERNSFILE>) {#lecture du fichier pour chaque ligne
	# Appel à  la procédure d'extraction des motifs
	&extract_pattern($ligne);#ligne du fichier pattern; arguments d'appels à la fonction
}

# Fermeture du fichiers de motifs
close(PATTERNSFILE);#

# routine de construction des chemins XPath
sub construit_XPath{
	# On récupère la ligne du motif recherché
	my $local_ligne=shift @_; #porte tous les paramètres de la fonction appelée
	
	# initialisation du chemin XPath
	my $search_path="";
	
	# on supprime avec la fonction chomp un éventuel retour à la ligne
	chomp($local_ligne);
	
	# on élimine un éveltuel retour chariot hérité de windows
	$local_ligne=~ s/\r$//;
	
	# Construction au moyen de la fonction split d'un tableau dont chaque élément a pour valeur un élément du motif recherché
	my @tokens=split(/ /,$local_ligne); 
	
	# On commence ici la construction du chemin XPath
	# Ce chemin correspond au premier noeud "element" de l'arbre XML qui répond au motif cherché 
	$search_path="//element[contains(data[\@type=\"type\"],\"$tokens[0]\")]";#cherche un élement qui a un sous-element "data"; 
	
	
	# Initialisation du compteur pour la boucle de construction du chemin XPath
	my $i=1;
	while ($i < $#tokens) {# s'arrête à dollar token -1
		$search_path.="[following-sibling::element[1][contains(data[\@type=\"type\"],\"$tokens[$i]\")]";#ramène tous frères cadtes et on veut lePREMIER ELEMENT
		$i++;
	}
	my $search_path_suffix="]";
	
	# on utilise l'opérateur x qui permet de répéter la chaine de caractère à sa gauche autant de fois que l'entier à sa droite,
	# soit $i fois $search_path_suffix
	$search_path_suffix=$search_path_suffix x $i; # CALCULE LE NBRE DE CROCHETS QU'IL FAUT
	
	# le chemin XPath final
	$search_path.="[following-sibling::element[1][contains(data[\@type=\"type\"],\"".$tokens[$#tokens]."\")]"
								.$search_path_suffix;# ON LES RAJOUTE ICI
		# print  "$search_path\n";

	# on renvoie à la procédure appelante le chemin XPath et le tableau des éléments du motif
	return ($search_path,@tokens);
}

# routine d'extraction du motif
sub extract_pattern{
	# On récupère la ligne du motif recherché
	my $ext_pat_ligne= shift @_;

	# Appel de la fonction construit_XPath pour le motif lu à la ligne courrante du fichier de motif
	my ($search_path,@tokens) = &construit_XPath($ext_pat_ligne);#récupère scalaire et liste et renvoie plusieurs élements

	# définition du nom du fichier de résultats pour le motif en utilisant la fonction join
	my $match_file = "res_extract-".join('_', @tokens).".txt";

	# Ouverture du fichiers de résultats encodé en UTF-8
	open(MATCHFILE,">:encoding(UTF-8)", "$match_file") or die "can't open $match_file: $!\n";
	
	# création de l'objet XML::XPath pour explorer le fichier de sortie tree-tagger XML
	
	# Parcours des noeuds du ficher XML correspondant au motif, au moyen de la méthode findnodes
	# qui prend pour argument le chemin XPath construit précédement
	# avec la fonction "construit_XPath"
	my @nodes=$root->findnodes($search_path);
	foreach my $noeud ( @nodes) {
		# Initialisation du chemin XPath relatif du noeud "data" contenant
		# la forme correspondant au premier élément du motif
		# Ce chemin est relatif au premier noeud "element" du bloc retourné
		# et pointe sur le troisième noeud "data" fils du noeud "element"
		# en l'identifiant par la valeur "string" de son attribut "type"
		my $form_xpath="";#on initialise vide
		$form_xpath="./data[\@type=\"string\"]";
		
		# Initialisation du compteur pour la boucle d'éxtraction des formes correspondants
		# aux éléments suivants du motif
		my $following=0;

		# Recherche du noeud data contenant la forme correspondant au premier élément du motif		
		# au moyen de la fonction "find" qui prend pour arguments:
		#			1. le chemin XPath relatif du noeud "data"
		#			2. le noeud en cours de traitement dans cette boucle foreach
		# la fonction "find" retourne par défaut une liste de noeuds, dans notre cas cette liste
		# ne contient qu'un seul élément que nous récupérons avec la fonction "get_node"
		# enfin nous en imprimons le contenu textuel au moyen de la méthode string_value
		print MATCHFILE $xpc->findvalue($form_xpath,$noeud);
		
		# Boucle d'éxtraction des formes correspondants aux éléments suivants du motif
		# On descend dans chaque noeud element du bloc
		while ( $following < $#tokens) {
			# Incrémentation du compteur $following de cette boucle d'éxtraction des formes
			$following++;
			
			# Construction du chemin XPath relatif du noeud "data" contenant
			# la forme correspondant à l'élément suivant du motif
			# Notez bien l'utilisation du compteur $folowing tant dans la condition de la boucle ci-dessus
			# que dans la construction du chemin relatif XPath
			my $following_elmt="following-sibling::element[".$following."]";			
			$form_xpath=$following_elmt."/data[\@type=\"string\"]";

			#	Impression du contenu textuel du noeud data contenant la forme correspondant à l'élément suivant du motif
			print MATCHFILE " ",$xpc->findvalue($form_xpath,$noeud);
		
			# Incrémentation du compteur $following de cette boucle d'éxtraction des formes
			# $following++;
		}
		print MATCHFILE "\n";
	}
	# Fermeture du fichiers de motifs
	close(MATCHFILE);
}